@echo off
echo ========================================
echo   bembu GPS-Watch Setup
echo ========================================
echo.

:: Admin-Check
echo Pruefe Berechtigungen...
net session >nul 2>&1
if errorlevel 1 goto NOADMIN
goto ADMIN

:NOADMIN
echo.
echo Installiere fuer aktuellen Benutzer (ohne Treiber)...
echo.
goto INSTALL

:ADMIN
echo OK - Admin-Rechte erkannt
echo.

:: Treiber installieren
if exist "drivers\arduino.inf" (
    echo Installiere USB-Treiber...
    pnputil /add-driver "drivers\arduino.inf" /install
    echo Treiber OK
echo.
) else (
    echo Hinweis: Keine Treiber im Paket
echo.
)

goto INSTALL

:INSTALL
echo Suche Update-Tool...

if exist "bembu_Updater.exe" goto FOUND
echo FEHLER: bembu_Updater.exe nicht gefunden!
pause
exit /b 1

:FOUND
echo Gefunden: bembu_Updater.exe
echo.

:: Installationsordner (benutzer-ordner = kein admin noetig)
echo Kopiere Dateien...

set DEST=%LOCALAPPDATA%\bembu
if not exist "%DEST%" mkdir "%DEST%"

copy "bembu_Updater.exe" "%DEST%\" >nul
echo OK: Tool kopiert

if exist "1.png" copy "1.png" "%DEST%\" >nul
if exist "2.png" copy "2.png" "%DEST%\" >nul
if exist "3.png" copy "3.png" "%DEST%\" >nul
if exist "4.png" copy "4.png" "%DEST%\" >nul

:: Desktop-Link
echo Erstelle Verknuepfung...

set LINK=%USERPROFILE%\Desktop\bembu GPS-Watch Update.lnk
set TARGET=%DEST%\bembu_Updater.exe

powershell -Command "$W=New-Object -ComObject WScript.Shell; $S=$W.CreateShortcut('%LINK%'); $S.TargetPath='%TARGET%'; $S.WorkingDirectory='%DEST%'; $S.Save()" >nul 2>&1

echo OK: Desktop-Link erstellt
echo.

:: Fertig
echo ========================================
echo   SETUP ABGESCHLOSSEN
echo ========================================
echo.
echo Installiert unter: %DEST%
echo.
echo Starte ueber: Desktop - "bembu GPS-Watch Update"
echo.

net session >nul 2>&1
if errorlevel 1 (
echo HINWEIS: Ohne Admin-Rechte installiert.
echo Falls die Uhr nicht erkannt wird:
echo   1. Dieses Setup ALS ADMIN ausfuehren
echo   2. ODER: Arduino IDE installieren
echo.
)

pause
